box2d实时绘制圆形方法之一:鼠标拖放方式

Box2D everyinch 1776℃ 0评论
package{
	import Box2D.Collision.Shapes.b2CircleShape;
	import Box2D.Collision.Shapes.b2PolygonShape;
	import Box2D.Common.Math.b2Vec2;
	import Box2D.Dynamics.b2Body;
	import Box2D.Dynamics.b2BodyDef;
	import Box2D.Dynamics.b2DebugDraw;
	import Box2D.Dynamics.b2FixtureDef;
	import Box2D.Dynamics.b2World;
	
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	
	[SWF(width="800",height="600",frameRate="32",backgroundColor="0x000000")]
	public class DrawCircle1 extends Sprite{
		private var world:b2World;
		private var timeStep:Number;
		private var iterations:uint;
		private var pixelsPerMeter:Number = 30;
		private var initX:Number = 0.0;
		private var initY:Number = 0.0;
		private var drawing:Boolean = false;
		
		public function DrawCircle1(){
			createWorld();
			makeDebugDraw();
			addGround(400/pixelsPerMeter,585/pixelsPerMeter,400/pixelsPerMeter,15/pixelsPerMeter);
			
			addEventListener(Event.ENTER_FRAME,onEnterframe);
			stage.addEventListener(MouseEvent.MOUSE_DOWN,onMouseDown);
			stage.addEventListener(MouseEvent.MOUSE_UP,onMouseUp);
		}
		
		private function createWorld():void{
			var gravity:b2Vec2 = new b2Vec2(0.0,9.8);
			var doSleep:Boolean = true;
			world = new b2World(gravity,doSleep);
			world.SetWarmStarting(true);
			timeStep = 1.0/30.0;
			iterations = 10;
		}

		private function makeDebugDraw():void{
			var debugDraw:b2DebugDraw = new b2DebugDraw();
			var debugSprite:Sprite = new Sprite();
			addChild(debugSprite);
			debugDraw.SetSprite(debugSprite);
			debugDraw.SetDrawScale(30.0);
			debugDraw.SetFillAlpha(0.5);
			debugDraw.SetLineThickness(1.0);
			debugDraw.SetFlags(b2DebugDraw.e_shapeBit | b2DebugDraw.e_jointBit);
			world.SetDebugDraw(debugDraw);
		}
		
		private function addGround(x:Number,y:Number,hx:Number,hy:Number):void{
			var bodyDef:b2BodyDef = new b2BodyDef();
			bodyDef.position.Set(x,y);
			var body:b2Body = world.CreateBody(bodyDef);
			var shape:b2PolygonShape = new b2PolygonShape();
			shape.SetAsBox(hx,hy);
			body.CreateFixture2(shape);
		}
				
		private function onMouseDown(e:MouseEvent):void{
			initX = e.localX;
			initY = e.localY;
			drawing = true;
			stage.addEventListener(MouseEvent.MOUSE_MOVE,onMouseMove);
		}
		
		private function onMouseMove(e:MouseEvent):void{
			if(drawing){
				graphics.clear();
				graphics.beginFill(0xFF0000,0.5);
				graphics.drawCircle(initX,initY,e.localX-initX);
			}
		}
		
		private function onMouseUp(e:MouseEvent):void{
			graphics.clear();
			drawing = false;
			
			var finalX:Number = e.localX;
			var finalY:Number = e.localY;
			
			var radius:Number = Math.abs(finalX-initX);
			if(radius > 0){
				addCircle(initX/pixelsPerMeter,initY/pixelsPerMeter,radius/pixelsPerMeter);
			}
		}
		
		private function addCircle(x:Number,y:Number,radius:Number):void{
			var bodyDef:b2BodyDef = new b2BodyDef();
			bodyDef.type = b2Body.b2_dynamicBody;
			bodyDef.position.Set(x,y);
			var circle:b2CircleShape = new b2CircleShape();
			circle.SetRadius(radius);
			var fixtureDef:b2FixtureDef = new b2FixtureDef();
			fixtureDef.shape = circle;
			fixtureDef.density = 1.0;
			fixtureDef.friction = 0.3;
			fixtureDef.restitution = 0.2;
			var body:b2Body = world.CreateBody(bodyDef);
			body.CreateFixture(fixtureDef);
		}

		private function onEnterframe(e:Event):void{
			world.Step(timeStep,iterations,iterations);
			world.ClearForces();
			world.DrawDebugData();
		}
	}
}



转载请注明:陈童的博客 » box2d实时绘制圆形方法之一:鼠标拖放方式

喜欢 (0)
发表我的评论
取消评论

表情

Hi,您需要填写昵称和邮箱!

  • 昵称 (必填)
  • 邮箱 (必填)
  • 网址

无觅相关文章插件,快速提升流量